datu-mota etiketadun mezuak erakusten. Erakutsi mezu guztiak
datu-mota etiketadun mezuak erakusten. Erakutsi mezu guztiak

2023(e)ko apirilaren 11(a), asteartea

FILE datu-mota



























DEFINIZIOA



FILE datu-mota edo fitxategi datu-mota informazio homogeneo gordetzen duen bilduma bat da. Datu-mota bera duten osagaien multzo bat da fitxategia eta disko zein zintetan egon ohi da. Fitxategia diskoan identifikatzeko STRING bat erabiliko dugu.



Fitxategiek array linealekin zerikusia dutelako jarraian datu-mota biren arteko alderaketa egingo dugu:




































Array datu-motaren eta Fitxategi datu-motaren arteko alderaketa

Array Fitxategi
Osagaiak Osagaiak datu-mota berekoak dira
 Osagaiak datu-mota berekoak dira
Atzipena Osagai bat identifikatzeko dagokion indizea erabiltzerik dago Osagai bat identifikatzeko fitxategiak erakusle bat dauka barneraturik
Tamaina Luzera maximoa aurredefiniturik dago Ez dago zertan aldez aurretik luzera definitu beharrik
Euskarria Memorian kokatzen da Memoriatik kanpo kokatzen da





ESKEMA



Hona hemen zenbaki errealak gordetzen dituen array baten eta fitxategi baten eskemak:




Fitxategiaren eskeman agertzen den egituran, lehenengo kontroleko notak diruditen zenbaki errealak biltzen dira eta lehenago esan dugun bezala memoriatik kanpo aurkitzen da. Memoriatik kanpo dagoen egitura horri fitxategi fisiko deritzo eta hura lantzeko beharrezkoa da FILE datu-motako frFitxategia aldagaia, FILE datu-motako frFitxategia aldagaiari fitxategi logiko esaten zaio eta aldagai guztiak bezala memorian kokaturik aurkitzen da.
DATU-MOTA SORTZEN



Zenbaki errealak gordetzeko fitxategiekin lan egiteko, lehenik FILE datu-mota bat deklaratuko dugu eta gero frFitxategia aldagaia sortuko dugu. Baina, diskoan dagoen fitxategiak izen bat du eta horregatik STRING bat erabili beharko dugu ere:





...
   type
      tfrFitxategia = file of real ;
      tsKateLuzea   = string[199] ; 
   var
      frFitxategiBat: tfrFitxategia ;  { fitxategi logikoa          }
      sFitxIzenBat  : tsKateLuzea ;    { fitxategi fisikoaren izena }
...




Diskoan dagoen informazioa atzitu ahal izateko sFitxIzenBat aldagaia erabiliko dugu eta fitxategiarekin lan egiteko frFitxategiBat aldagaia (FILE datu-motatakoa) beharko dugu. Bi aldagaiak, noski, konputagailuaren memorian kokatzen dira. Baina, diskoan dauden fitxategiaren datuak ez dira kokatzen konputagailuaren memorian.





Diskoan kokaturik dagoen egiturari fitxategi fisiko esango diogu. Adibidez, zenbaki errealak biltzen dituen Datuak.dat izeneko egiturari fitxategi fisiko esaten diogu eta hona hemen bere balizko eskema bat:







Fitxategi logikoa adierazten duen frFitxategiBat aldagaia eta diskoan dagoen fitxategi fisikoa elkar uztartzeko assign prozedura daukagu, eta elkarketa egiteko fitxategi fisikoaren izenaren bitartez lortzen da, STRING baten bitartez alegia. Demagun sFitxIzenBat aldagaiaren edukia 'Datuak.dat' balioa dela. Ikusi eskema hauetan assign(frFitxategiBat,sFitxIzenBat) prozedura aplikatu aurreko egoera eta prozedura aplikatu ondoko egoera:

OINARRIZKO ERAGIKETA: FITXATEGITIK IRAKURRI



Fitxategi fisikoan, diskoan, dagoen datu bat memoriara ekartzeko irakurketa bat egin behar da. Demagun frFitxategiBat aldagaia (FILE datu-motatakoa) daukagula eta assign(frFitxategiBat, sFitxIzenBat) bitartez uztartu egin dugula 'Datuak.dat' izena duen diskoko fitxategiarekin.



FILE datu-motako frFitxategiBat aldagaia behar da Datuak.dat fitxategitik datu bat irakurtzeko:


read(frFitxategiBat, rElem);      readln(frFitxategiBat, rElem);

Non rElem memorian dagoen aldagaia den eta fitxategiko datua jasoko duen. Ikusi eskema:



Irakurketa bakoitzeko elementu bakar bat irakur daiteke, fitxategiaren erakusleak adierazten duen elementua hain zuzen ere. Irakurketa gertatu ondoren erakusleak aurrera egiten du.

OINARRIZKO ERAGIKETA: FITXATEGIAN IDATZI



Memorian dagoen datu bat diskoan gordetzeko, idazketa bat egin beharko da diskoan. Demagun lehen bezala, daukagun frFitxategiBat aldagaia uztartu dugula 'Datuak.dat' izena duen diskoko fitxategiarekin. Memorian aurkitzen den rElem aldagaian 7.05 datua dago.



Honela idazten da datu hori fitxategi batean, lehen bezala frFitxategiBat aldagaiaren bitartez:

write(frFitxategiBat, rElem);      writeln(frFitxategiBat, rElem);

Memorian dagoen rElem aldagaiaren edukia fitxategian idatzi. Ikusi eskema:





Hasieran, fitxategia hutsik egon da (fitxategiaren amaierako marka 0 posizioan dagoelako) horregatik fitxategiaren erakuslea 0 posizioan kokaturik egon da. Idazketa burutu ondoren, datu berri bat dago fitxategian eta erakusleak aurrera egiten du 1 posizioan kokatuz.



rElem aldagaiaren edukia berriztuz eta bigarren idazketa bat eginez gero, egoera honako hau izango litzateke, ikusten denez fitxategia luzatu egiten da elementu berri bat daukalako:





Baina hirugarren idazketa bat egin aurretik fitxategiaren erakuslea tokiz aldatzen badugu (horretarako seek prozedura erabili behar da), adibidez dagoen tokitik bat atzera egin dezala erakusleak, orduan idazketaren emaitza bestelakoa da. Izan ere, fitxategiaren elementua ordezkatzen du fitxategia luzatu gabe. Beraz, hau da erakuslea posizio bat atzeratzeko agindua seek(frFitxategiBat, filepos(frFitxategiBat)-1) eta hurrengo idazketa burutu aurretiko egoera irudi honetan erakusten da:




Hurrengo idazketa gauzatu osteko irudia:




Ikusten da rElem aldagaiaren edukia berria 5.91 dela eta erakusleak posizio bat atzera egin duela (2-tik 1 posiziora). Idazketa orain burutzean, elementu berria 1 posizioan gordeko da.



Idazketa burutu ondoren: elementu berriak zaharra ordezkatu du, erakusleak aurrera egin du (2 posizioan kokatuz), eta, ondorioz fitxategiaren luzera ez da aldatu.



Ikusi ere Fitxategiak: non gaude? artikulua.

I
 




LAN EGITEKO BALIABIDEAK



Fitxategiekin trebatzeko adibide-ariketa batzuk prestatu dira. Adibide-ariketak bederatzi dira eta exekutatu aurretik agindu hauek jarraitu:



  1. Iturburu-programak horiek bederatzi dira eta osoen fitxategiekin lan egiten dute

  2. Iturburu-programak zenbatuta daude eta zenbakiek adierazten duten sekuentzia gordez iturburu-programak konpilatu, exekutatu eta emaitzak interpretatu

  3. Jarraian ematen diren bederatzi adibide-programak hartu eta direktorio batean gorde, edozein karpetatan gorde dezakezu, adibidez Programak delako direktorioan

  4. Iturburu-programak konpilatzean Programak direktorio horren barruan sortuko dira programa exekutagarriak
  5. C: diskoaren erroan NereDatuak izeneko karpeta bat sortu, non datu-fitxategiak egongo diren, adibidez C:\NereDatuak\Zenbakiak.dat datu-fitxategia



Adibide-ariketak:



  • 1FitxategianGorde.pas fitxategi bat sortu rewrite prozeduraren bitartez, hamar datu idatzi fitxategian, eta bukatzeko fitxategiaren edukia pantailaratu




  • 2FitxategiaIrakurri.pas existitzen den fitxategia zabaldu reset prozeduraren bitartez, eta dituen hamar elementuak pantailaratu





  • 3FitxategiarenExistentzia.pas fitxategi existitzen den ala ez aztertu fileexists funtzioa erabiliz, funtzio honek sysutils unitatea behar du, horregatik programaren hasieran uses sysutils agindua derrigorrezkoa da




  • 4FitxategiaEOF.pas fitxategiaren erakuslea fitxategiaren bukaeran dagoenean eof funtzio boolearrak TRUE itzultzen du, End Of File egia baita





  • 5FitxategiaSeekFilePos.pas hurrengo idazketa ala irakurketa fitxategiaren zein posiziotan gertatuko den Seek prozedura eta filepos funtzioarekin bermatuko dugu, fitxategiak zenbat elementu dituen ezagutzeko filesize funtzioa erabil daiteke (gogoratu Fitxategiak: non gaude? artikulua)





  • 6FitxategiaMoztu.pas zabalik aurkitzen den fitxategia moztu truncate prozeduraren bitartez, erakusleak adierazten duen posiziotik aurrerako datuak galduz





    procedure FitxategiaMoztu(sFitxIzen: tsKatea);
    var
       fFitxategia: tfFitxategia;
       iPosizioa  : integer;
    begin
       assign(fFitxategia, sFitxIzen);
       reset(fFitxategia);

       repeat
          writeln(sFitxIzen,
                  ' fitxategiaren datuen indizeak: 0..',
                  FileSize(fFitxategia)-1);

          write('Zein elementutik moztu nahi duzu? ');
          readln(iPosizioa);
       until (iPosizioa >= 0) and
             (iPosizioa <= FileSize(fFitxategia)-1);

       seek(fFitxategia, iPosizioa);    { mozteko kokatu   }
       truncate(fFitxategia);           { fitxategia moztu }

       close(fFitxategia);              { fitxategia itxi  }
    end;









  • 7FitxategiaEzabatu.pas itxita aurkitzen den fitxategia ezabatu erase prozeduraren bitartez, fitxategia diskotik ezabatuko da





    procedure FitxategiaEzabatu(sFitxIzen: tsKatea);
    var
       fFitxategia: tfFitxategia;
    begin
       assign(fFitxategia, sFitxIzen);  { fitxategia uztartu }
                                        { baina ez ireki     }
       erase(fFitxategia);              { fitxategia itxita  }
    end;                                { dagoenez ezabatu   }









  • 8FitxategiaBerrizendatu.pas itxita aurkitzen den fitxategiari bere izena aldatu rename prozeduraren bitartez, fitxategia diskotik ez da desagertuko baina izen berri bati esker atzitu ahalko dugu






    procedure FitxategiaBerrizendatu(sFitxIzenZahar: tsKatea;
                                     sFitxIzenBerri: tsKatea);
    var
       fFitxategia: tfFitxategia;
    begin
       assign(fFitxategia, sFitxIzenZahar);  { fitxategia uztartu    } 
                                             { baina ez ireki        } 
       rename(fFitxategia, sFitxIzenBerri);  { fitxategia itxita     } 
    end;                                     { dagoenez berrizendatu }







  • 9FitxategiakEtaParametroak.pas prozedura eta funtzioetara fitxategiaren izena pasatuko da; azpiprograman definituko da file datu-motatako aldagaia, azpiprogramaren hasieran assign egingo da, gero reset/rewrite (bietariko bat, egoerari dagokiona), gero datuekin lan egingo da (read/write) eta azpiprogramaren azkenean fitxategia itxi beharko da close bat erabiliz






FITXATEGIAK PARAMETRO BEZALA




Fitxategiak lantzen dituen errutinak idaztean aukera bi izango ditu programatzaileak, fitxategi logikoa bidaltzea azpiprogramara (file datu-motako aldagaia) edo bestela fitxategi fisikoaren izena igortzea azpiprogramara (string datu-motako aldagaia).





Guk bigarren bidea erabiliko dugu, hots, azpiprogrametara fitxategi fisikoaren izena bidaliko dugu string aldagai baten bitartez. Kontutan izan dezagun, nahiz eta azpiprogramaren barruan fitxategia aldatua izan, bere izena aldatzen ez den bitartean parametroa sarrerakoa izango dela (baliozko parametroa alegia).









Azpiprogrametan fitxategiekin lan egiteko hiru urrats emango dira:


  1. Fitxategi logikoa eta fitxategi fisikoa assign bitartez elkartu, gero fitxategia ireki reset (edo rewrite) prozedura erabiliz

  2. Idazketa edo/eta irakurketa operazioak burutu (write edo/eta read prozedurak)

  3. Fitxategia itxi close bitartez itxi










Fitxategiaren izena kate bat da eta gogoratu string datu-mota sinplea dela. Horregatik, azpiprograma batean honela agertuko da jokamoldearen arabera:


  • Fitxategiaren izena irteerakoa denean var marka izango du aurrean

  • Fitxategiaren izena sarrerakoa denean ez du inolako markarik izango









    FITXATEGIEN GAINEKO ERAGIKETAK




    Hurrengo puntuetan fitxategien gaineko zenbait eragiketa azalduko dugu, eragiketok beti azpiprogrametan gauzatuko ditugu eta horrela programa konplexu batetarako oinarrizko software zatiak izan daitezke.



    Erregistroen fitxategiak landuko ditugu. Beraz hemendik aurrera honelako definizioa sarritan ikusiko dugu, non fitxategiaren elementuaren oinarria hiru eremuko erregistroa den: 








    type 
       tsKate49 = string[49];
       trdFitxa = record
                     sIzenDeiturak: tsKate49;
                        byDeialdia: byte;
                             rNota: real;
                  end;
       tfrdFitxategi = file of trdFitxa;

























    Hiru eremu dira eta aurrerago ikusiko dugunez, haien arteko ordena erlatiboa garrantzizkoa da. Hau da, lortzen den datu-fitxategiaren elementu bakoitza tsKate49-byte-real ordena hori jarraituz gordetzen da fitxategian.











    FITXATEGIA SORTU



    FitxategiaSortu.pas adibidean fitxategi berri bat sortu eta trdFitxa datu-motako erregistroak fitxategian gordetzen dira.






    FITXATEGIAREN EXISTENTZIA



    FitxategiaSortuFitxategiaIkusi.pas adibidean existitzen ez den fitxategia sortzen da, ala prozesatu egiten da lehendik existitzen bazen. Gogoratu ere lehenago ikusi dugun 3FitxategiarenExistentzia.pas adibidea eta 9FitxategiakEtaParametroak.pas adibidea non fitxategi baten existentzia aztertzen den fileexists funtzioa erabiliz.






    FITXATEGI OSOA PROZESATU



    Fitxategiaren elementu guztiei eragiketa bera aplikatzen zaion kasua da hau, adibidez:


    • FitxategiOsoaProzesatu1.pas adibidean existitzen den fitxategi baten edukia erakusten da

    • FitxategiOsoaProzesatu2.pas adibidean fitxategiaren elementu guztien byDeialdia datuak unitate batean inkrementatzen dira

    • FitxategiOsoaProzesatu3.pas adibidean fitxategi baten informazioa beste bi fitxategi berrien artean banatzen da: 1. deialdiko ikasleak Berriak.DAT fitxategira eta gainerakoak Besteak.DAT fitxategira

    • FitxategiOsoaProzesatu4.pas adibidean fitxategiaren nota maximoa duen elementuaren posizioa zehazten da, ondoren nota maximoa lortu duen ikaslearen datuak pantailaratzen dira








    BILAKETA FITXATEGIAN



    BilaketaFitxategian.pas izeneko adibidean sIzenDeiturak eremuari dagokion datu bat irakurtzen da programa nagusian, ondoren funtzio batean datu horren bilaketa gauzatzen da. Funtzio baten bitartez itzuli elementuaren posizioa fitxategian, elementua ez badago itzuli -1 marka.






    GEHIKETA FITXATEGIAN



    GehiketaFitxategian.pas izeneko adibidean fitxategi bati elementu berri bat gehitzen zaio (fitxategiaren bukaeran, noski).






    FITXATEGIAREN DATU BATEN ALDAKETA



    DatuBatenAldaketa.pas izeneko adibidean ikasle bati dagokion rNota eremuko balioa aldatu behar zaio. Lehenik, aldatu behar den elementuaren bilaketa egiten da eta gero aldaketa gauzatzen da. Baina kontuz, nahiz eta elementuaren eremu bakarra aldatu nahi izan, fitxategitik irakurtzean edo fitxategian idaztean elementu osoa prozesatzen da.






    FITXATEGIAN ELEMENTU BAT TARTEKATU



    Eragiketa hau egiteko array laguntzaile bat erabiliko dugu (ikusi hurrengo bi atalak: F→A eta A→F). Gogoratu arrayen algoritmoak, konkretuki Txertaketa (arrayaren k posizio ezagun batean elementu berri bat txertatu edo tartekatu). Hauxe da DatuBatenTxertaketa.pas izeneko adibidea.






    FITXATEGITIK ELEMENTU BAT KENDU



    Kendu beharreko elementua azkena bada truncate prozedura aplika dezakegu, gainerako kasuetan array laguntzaile bat erabiliko dugu (ikusi hurrengo bi atalak: F→A eta A→F). Bi bide:


    1. Gogoratu arrayen algoritmoak, konkretuki Ezabaketa (arrayaren k posizio ezagun batean dagoen elementua ezabatu). Hauxe da DatuBatenEzabaketa.pas izeneko adibidea

    2. F→A prozesua egitean kendu behar dugun elementua ez pasatu fitxategitik arrayra. Hauxe da DatuBatenEzabaketaErrazagoa.pas izeneko adibidea








    FITXATEGITIK ELEMENTU BATZUK KENDU



    Kendu beharreko elementuek baldintza bera betetzen dute. F→A prozesua egitean kendu behar ditugun elementuak saihestu (ez pasatu) fitxategitik arrayra. Hauxe da DatuBatzuenEzabaketa.pas izeneko adibidea.






    FITXATEGI BAT SAILKATU/ORDENATU

    HAU EZ. Ez da azterketan galdetuko baina proiektuan erabil daiteke.




    Eragiketa hau egiteko array laguntzaile bat erabiliko dugu (ikusi hurrengo bi atalak: F→A eta A→F). Gogoratu arrayen elementuen Sailkatzea/Ordenatzea nola lortzen zen. Hona hemen bi adibide:


    • Sailkatze arrunta eremu bakar baten arabera. FitxategiaSailkatu.pas izeneko adibidean fitxategia rNota eremuaren arabera sailkatzen denez nota baxuena duten erregistroak fitxategiaren hasieran kokatzen dira eta nota altuko erregistroak fitxategiaren bukaeran egongo dira

    • Sailkatze aurreratua (bi eremuen araberakoa). FitxategiaSailkatu_SailkatzeAurreratua.pas izeneko adibidean fitxategia byDeialdia eremuaren arabera sailkatzen da, eta deialdi berdina duten bi erregistroen kokapena erabakitzeko sIzenDeiturak eremuari begiratzen zaio ordena alfabetikoa zainduz. Gauza bera egiten da FitxategiaSailkatu_2EremukoSailkatzeAurreratua.pas izeneko adibidean










    FITXATEGI → ARRAY



    F → A algoritmoan informazioa diskoko fitxategi batean dago eta memoriako array batera eraman nahi da. Ikusi FitxategitikArrayra.pas programa non C:\Tokia\ karpetako fitxategi batetik abiatuta memoriako array bat elikatzen duen. Programaren zatirik interesgarriena prozedura hau da:








       procedure FitxategiArray(var ardGela: tardZerrenda;   
                                var iLuzera: integer; 
                                  sFitxIzen: string);
       var
          f     : tfrdFitxategi;
          rdElem: trdFitxa;
       begin
          assign(f, sFitxIzen);
          reset(f);

          iLuzera := 0;
          while not eof(f) do
          begin         
             read(f, rdElem);
             iLuzera := iLuzera +1;
             ardGela[iLuzera] := rdElem;
          end;

          close(f);
       end;









    Fitxategia ireki eta fitxategia bukatzen ez den bitartean, itzuli bakoitzeko, elementu bat fitxategitik irakurri eta memorian dagoela arrayean gorde.


     


     


     


     


     








     


     


     


     


     


     











    ARRAY → FITXATEGI



    A → F algoritmoan informazioa memoriako array batean daukagu eta diskoko fitxategi batera igaro nahi da. Aurreko F→A programa ikusirik, erraz ulertzen da array batean daukagun informazioa fitxategi batera eramateko prozedura hau:











       procedure ArrayFitxategi(const ardGela: trdZerrenda;  
                                      iLuzera: integer; 
                                    sFitxIzen: string);
         var
            f       : tfrdFitxategi;
            rdElem  : trdFitxa;
            iIndizea: integer; 
         begin
            assign(f, sFitxIzen);
            rewrite(f);

            for iIndizea:=BEHEMUGA to iLuzera do
            begin
               rdElem := ardGela[iIndizea];
               write(f, rdElem);
            end;

            close(f);
         end;












    FitxategitikArrayra.pas programari A → F algoritmoa gehitu zaio, eta FitxategiArrayFitxategi.pas programa berri honek array baten informazioa C:\Tokia\ karpetako fitxategi batean gordetzen da.



    FitxategitikArrayra.pas programari A → F algoritmoa gehitu zaio, eta FitxategiArrayFitxategi.pas programak eskema honi jarraitzen dio F → A → F non algoritmoak hasieran fitxategitik arrayra darama informazioa (edo informazioaren zati bat) eta ondoren arraytik fitxategira dakar berriro.






    DATU-FITXATEGI BAT LANTZEKO PROGRAMAK (I)



    Landu edo prozesatu nahi dugun fitxategiaren barne egitura eta fitxategi horri dagokion programaren datu-motak elkar estuki lotuta daude. Ezin da edozein fitxategi edozein programaren bitartez prozesatu. Hiru iruditan azal dezagun.




    0.

    C:\31_Taldea.dat datu-fitxategiarekin lan egingo dugu, eta ondoko programek prozesuatuko dute C:\31_Taldea.dat datu-fitxategia:





    1.

    Esate baterako, har eta exekuta dezagun gorago erakutsi den FitxategiaSortu.pas programa zeinek honelako egituradun fitxategia sortzen duen:



      type 
         tsKate49 = string[49];
         trdFitxa = record
                       sIzenDeiturak: tsKate49;
                          byDeialdia: byte;
                               rNota: real;
                    end;
         tfrdFitxategi = file of trdFitxa;



    Ondoko irudian ikusten da FitxategiaSortu.pas programaren balizko exekuzio bat, non C:\31_Taldea.dat izeneko fitxategian hiru ikasleen datuak gordetzen diren:




    2.

    Orain gorago ikusitako FitxategiOsoaProzesatu1.pas programaren bitartez C:\31_Taldea.dat izeneko fitxategi hori prozesatuko dugu. Ez ahaztu FitxategiOsoaProzesatu1.pas programak dituen datu-motak hauexek direla:



      type 
         tsKate49 = string[49];
         trdFitxa = record
                       sIzenDeiturak: tsKate49;
                          byDeialdia: byte;
                               rNota: real;
                    end;
         tfrdFitxategi = file of trdFitxa;



    Programaren datu-motak eta fitxategiaren barne egitura bat datoz, horregatik FitxategiOsoaProzesatu1.pas programaren exekuzioak egoki erakusten du C:\31_Taldea.dat izeneko fitxategian edukia:







    3.

    Gorago ikusitako FitxategiOsoaProzesatu1.pas programari aldaketa txiki bat egingo diogu FitxategiOkerraOsokiProzesatu.pas deituz. Programa bien arteko aldea bi eremuen ordenan datza (lehenik rNota eta ondoren byDeialdia). Programa berriak dituen datu-motak hauexek dira:



      type 
         tsKate49 = string[49];
         trdFitxa = record
                       sIzenDeiturak: tsKate49;
                               rNota: real;
                          byDeialdia: byte;
                    end;
         tfrdFitxategi = file of trdFitxa;



    Ondorioz FitxategiOkerraOsokiProzesatu.pas programa exekutatzean eta C:\31_Taldea.dat fitxategia erakustean ondoko hau agertuko da:





    Goiko irudian argi dago emaitza okerra dela. Zergatik?  C:\31_Taldea.dat izeneko fitxategiaren barne egitura eta FitxategiOkerraOsokiProzesatu.pas
    programaren datu-motak bat ez datozelako.
    DATU-FITXATEGI BAT LANTZEKO PROGRAMAK (II)



    Ikusi dugu prozesatu nahi dugun fitxategiaren barne egitura eta dagokion programaren datu-motak elkar estuki lotuta daudela. Baina zer neurriraino? Jarraian datu-moten identifikadoreak mintzagai ekarriko ditugu, erakutsiko dugu datu-moten identifikadoreen izenak garrantzitsuak ez direla. Hots, erregistro baten eremuen ordena zaintzea ezinbestekoa dela; horrez gain, ezinbestekoa direla ere datu-moten tamainak eta izaerak. Erregistroekin ari garela, bere eremuen ordena eta datu-motak berdin-berdinak izan behar dira fitxategiaren barne egituran eta hura prozesatzeko programaren datu-motetan.



    Lehen bezala hiru iruditan azalduko dugu. Lehen bi irudien datu-motak berdinak dira eta hirugarren irudirako datu-moten identifikadoreak moldatu ditugu.



    1. eta 2.

    Jarraian erakusten dira FitxategiaSortu.pas programak zer datu-motak erabiltzen dituen, eta FitxategiOsoaProzesatu1.pas programak datu-mota berberak erabiltzen dituenez C:\31_Taldea.dat izeneko fitxategiaren edukia bistaratzeko ez da arazorik izango. Guk aukeratutako identifikadoreak beltzez adierazi ditugu:



      type 
         tsKate49 = string[49];
         trdFitxa = record
                       sIzenDeiturak: tsKate49;
                          byDeialdia: byte;
                               rNota: real;
                    end;
         tfrdFitxategi = file of trdFitxa;



    Ondoko bi irudietan ikusten da FitxategiaSortu.pas programaren balizko exekuzio bat eta FitxategiOsoaProzesatu1.pas programaren exekuzioa, non C:\31_Taldea.dat izeneko fitxategiaren edukia zuzentasunez pantailaratzen den:










    3.

    FitxategiOsoaProzesatu1.pas programa aldatuko dugu FitxategiOsoaProzesatu1_ALDATUA.pas sortuz. Aldaketaren zioa identifikadore berriak asmatzea da, honako hauek aukeratu ditugu:



      program FitxategiOsoaProzesatu1_ALDATUA;
      type 
         tsKate99 = string[99];
         tsKate49 = string[49];
         trdFitxa = record
                                    sNor: tsKate49;
                       byDeialdiZenbakia: byte;
                           rKalifikazioa: real;
                    end;
         tfrdFitxategi = file of trdFitxa;





    Identfikadore berrien datu-motak irudi honetan jaso dira:





    FitxategiaSortu.pas programaren bitartez C:\31_Taldea.dat izeneko fitxategia sortu ondoren FitxategiOsoaProzesatu1_ALDATUA.pas exekutatu eta datuak ondo ikusiko dira:







    FITXATEGI TALDE BAT PROZESATU

    HAU EZ. Ez da azterketan galdetuko, baina proiektuan erabil daiteke.



    Demagun 5 fitxategi prozesatu behar ditugula eta landu behar ditugun fitxategi horien izenak Datuak_XY.dat itxurakoak diren, non XY digituak diren. Adibidez, landu behar ditugun fitxategiak hauek izan daitezke: Datuak_01.dat, Datuak_02.dat, Datuak_03.dat, Datuak_04.dat eta Datuak_05.dat.



    Esan dugunez, talde horretako fitxategi bakoitzari prozesaketa bera aplikatu behar diogu. Adibidez, suposatu taldeko fitxategi bakoitzaren azken elementua ezabatu nahi dela. Hementxe ematen da ariketa horren programa:









    Aurreko kasuan fitxategien izenak antolaketa bat daukate, baina gerta daiteke fitxategien izenek legerik ez jarraitzea. Bigarren kasu honetan fitxategien taldea beste modu batez osatu beharko da. Esate baterako, taldea osatzen duten fitxategien izenak array batean gorderik egon daizteke, adibide honetan bezala:








    Diskoarekin lan egiteko:



    • GetCurrentDir funtzioa, ez du parametrorik behar eta uneko direktorioa itzultzen du karaktere-kate batean 

    • Chdir prozedura, karaktere-kate bat hartzen du sarrerako parametrotzat eta uneko direktorio aldatzen du, uneko direktorio berria karaktere-kateak adierazitakoa izango da










    • diskoa unitatea, 33. Ariketa: unitateak (III) adibidean ikus daitekeen bezala bi zeregin betetzeko balio du: 


      1. DirektorioarenEdukia prozedurak direktorio baten edukiaren informazioa (fitxategiak eta direktorioak) pantailaratzen du, karaktere-kate bat behar du fitxategien izenek bete behar duten moldea adierazten duen karaktere katea

      2. FitxategienIzenak prozedurak direktorio baten fitxategien izenak array batean itzultzen ditu












    DATU-FITXATEGIAK NON SORTZEN DIRA?

    HAU EZ. Ez da azterketan galdetuko, baina jakin behar da.



    Azalpen hauek Direktorioak: Non gaude? artikuluan eman dira ere.



    Datu-fitxategia sortzeko fitxategiaren izenari erreparatzen zaio eta bi egoera izan daitezke. Bat, fitxategiaren izena ematean diskoaren kokapen zehaztu izana, adibidez C:\Tokia\Datuak.dat non Tokia karpeta aldez aurretik sorturik egon behar den. Bi, fitxategiaren izena ematean diskoaren kokapenik ez den zehazten, adibidez Datuak.dat non karpetarik ez den adierazi. Egoera biak ikus ditzagun:



    1.

    Fitxategiaren izena ematean C:\Tokia\Datuak.dat katea erabili bada, orduan C: diskoaren erroaren \ menpe dagoen Tokia izeneko karpetan sortuko da Datuak.dat fitxategia. Ikusi esate baterako 1FitxategianGorde.pas adibidea.



    2a.

    Fitxategiaren izena ematean Datuak.dat katea erabili bada eta Dev-Pas programazio-ingurunea erabilita iturburu-programa konpilatzen badugu programa exekutagarria eskuratuko dugu;  Dev-Pas programazio-ingurunetik irten gabe programa exekutagarria exekutatzen badugu, orduan Datuak.dat fitxategia Dev-Pas programazio-ingurunearen direktorioan sortuko da, adibidez C:\Dev-Pas karpetan. Ikusi FitxategiaSortu_BiderikGabe_IngurunetikExekutatzen.pas adibidea.

    C:\KarpetaBat direktorioan gaudela .PAS iturburu-programa konpilatu
    eta .EXE programa exekutagarria lortuko da C:\KarpetaBat karpetan




    Programazio-ingurune barrutik .EXE programa egikaratzean Datuak.dat
    fitxategia C:\Dev-Pas direktorioan sortuko da biderik ez bada zehaztu





    2b.

    Fitxategiaren izena ematean Datuak.dat katea erabili bada eta Dev-Pas programazio-ingurunea erabilita iturburu-programa konpilatzen badugu programa exekutagarria eskuratuko dugu, adibidez FitxategiaSortu_BiderikGabe_ExekutagarriaExekutatzen.pas iturburu-programatik abiatuta FitxategiaSortu_BiderikGabe_ExekutagarriaExekutatzen.EXE programa exekutagarria lor daiteke. Programazio-ingurunea alde batera utzita FitxategiaSortu_BiderikGabe_ExekutagarriaExekutatzen.EXE programa exekutagarria diskoaren edozein karpetara kopiatuta eta bertan exekutatuta, lortuko den Datuak.dat fitxategia programa exekutagarriaren karpeta horretan sortuko da.


    C:\KarpetaBat direktorioan gaudela .PAS iturburu-programa konpilatu
    eta .EXE programa exekutagarria lortuko da C:\KarpetaBat karpetan





    C:\BesteKarpetaBat karpetan dagoen .EXE programa
    gainean kokatu eta klik eginez hura egikaratu





    C:\BesteKarpetaBat karpetan dagoen .EXE programa egikaratzean
    Datuak-dat fitxategia sortuko da. Baina, non sortuko da?





    C:\BesteKarpetaBat karpetako .EXE programa egikaratu ondoren
    bertan sortuko da Datuak-dat fitxategia biderik ez bada zehaztu









    ADIBIDEAK



    Hona hemen fitxategien zenbait programa:

















    INTEGER REAL BOOLEAN CHAR STRING ARRAY RECORD FILE




     


    ordua: iruzkinik ez:
    Etiketak: , ,

    2023(e)ko apirilaren 4(a), asteartea

    RECORD datu-mota


























    DEFINIZIOA


    RECORD edo erregistro datu-mota, ataletan antolatzen den datu-mota egituratua da. Erregistro batek dituen elementuak eremuak deitzen dira eta eremuen datu-mota desberdinak izan daitezke elkarrekiko, erregistroaren elementu kopurua finitua da eta eremu bakoitzaren atzipena identifikadore baten bitartez gauzatzen da.

    ESKEMA
    DATU-MOTA SORTZEN



    Erregistro datu-mota bat deklaratzean, eremuak izendatzeko identifikadorea erabaki behar da eta eremu bakoitza zein datu-motatakoa izango den.



    Eskeman erakusten den rdIkaslea delako aldagaia lortzeko, aurretik deklarazio hau egin beharko da:





    ...
            type
               trdIkasle = record
                                 sIzena: string[39] ;
                                  rNota: real ;
                              sHelbidea: string[99] ; 
                                byAdina: byte ;
                           end ;
            var
               rdIkaslea: trdIkasle ;
               rdIrakaslea: trdIkasle ;
    ...




    Ondorioz rdIkaslea eta rdIrakaslea bi aldagaiak datu-mota bera daukate oinarrian eta biak bat datoz goi-goian erakutsi den eskemarekin.



    Erregistro aldagai batean datuak gordetzeko, aldagaiaren identifikadorea eta eremuaren identifikadorea idatzi behar dira horien artean lokailu bat jarri beharra dago. Pascal lengoaiak identifikadore biren arteko elkarketa gauzatzeko puntu bat darabil, horrelaxe:



    writeln(rdIkaslea.sIzena) ;

    readln(rdIkaslea.rNota) ;

    Puntua ken daiteke WITH klausula erabiltzen bada, aurreko aginduak honelaxe idatziko lirateke:


    with rdIkaslea do

    begin
           writeln(sIzena) ;
           readln(rNota) ;

    end ;
    ERAGIKETAK: IDATZI-IRAKURRI ETA ESLEIPENA



    Erregistro bat ezin daiteke ez irakurri ez idatzi, horregatik ondoko aginduak okerrak dira:


    writeln(rdIkaslea) ;     { HAU GAIZKI DAGO }

    readln(rdIrakaslea) ;    { HAU GAIZKI DAGO }

    Aurreko adibidearen erregistroaren eremuak idatz edo irakur daiteke, eta ondorioz agindu hauek zuzenak dira:


    writeln(rdIkaslea.sIzena) ;

    readln(rdIkaslea.rNota) ;

    Erregistro bati aplika dakioken eragiketa bakarra esleipena da, ondoko agindu hau zuzena da:



    rdIkaslea := rdIrakaslea ;


    ERAGIKETAK: KONPARAKETAK



    Esan den bezala, erregistroek onartzen duten eragiketa bakarra asignazioa da. Hori dela eta, ezin daiteke erregistroen arteko konparaziorik egin. Labur azalduz:


    • 6 konparatzaileetatik lau hauek ez dute zentzu handirik erregistroekin: <, >, <= eta >=



    • 6 konparatzaileetatik beste biek (= eta <>) zentzua izan dezakete erregistroekin baina bi erregistroen arteko alderaketa ezin daiteke honela egin:




    if rdIkasle1 = rdIkasle2 then   { HAU GAIZKI DAGO }

    if rdIkasle1 <> rdIkasle2 then  { HAU GAIZKI DAGO }


    Horregatik erregistro bik informazio berdina gordetzen dutela frogatzeko eremuka lan egingo da. Konparaketa helburu horrekin, ErregistroBiBerdinakOteDiren izeneko adibidean, funtzio boolear bat garatu da.



    ERREGISTROAK ETA ARRAYAK



    Sarritan erregistroak eta arrayak elkarrekin konbinatzen dira. Esate baterako, jarraian erregistroen array bat deklaratzen da: 





    ...
            type
               trdIkasle = record
                              sIzena: string[39] ;
                               rNota: real ;
                           end ;
               tardTalde = array[1..80] of trdIkasle ;
            var
               ardIkasgela: tardTalde ;
               iLuzera: integer ;
               Indize: integer ;
    ...




    Datuak sartu eta eskema bat eginez:







    Datuak sartu ondoren, ikusi nola eskuratuko genukeen irudiko P hori. Honelaxe zehaztuko genuke:


    • ardIkasGela arraytik abiatuta

    • Indize aldagaiak 2 balioa duelarik, arrayaren bigarren elementu hau ardIkasGela[2]erregistro bat da...

    • eta sIzena eremua hartzean, hots, ardIkasGela[2].sIzena string bat da...

    • eta string horren bere lehen karakterea eskuratzeko ardIkasGela[2].sIzena[1]erabiliko dugu


    ARRAYAK ERREGISTROETAN



    Erregistro baten eremu bat array bat izan daiteke. Esate baterako, jarraian array bat daukan erregistro bat deklaratzen da:





    ...
            type
               tasKateak = array [1..3] of string[39] ;
               trdIkasle = record
                              asIzenDeiturak: tasKateak ;
                                       rNota: real ;
                           end ;
            var
               rdIkaslea: trdIkasle ;
    ...




    Datuak sartu eta eskema bat eginez:









    Datuak sartu ondoren, ikusi nola eskuratuko genukeen irudiko M hori. Honelaxe zehaztuko genuke:


    • rdIkaslea erregistrorik abiatuta

    • rdIkaslea.asIzenDeiturak array bat da eta...

    • bere hirugarren elementua rdIkaslea.asIzenDeiturak[3]izanik, badakigu string bat dela

    • eta bere lehen karakterea eskuratzeko rdIkaslea.asIzenDeiturak[3][1]erabiliko dugu


    ERREGISTROAK ERREGISTROETAN



    Erregistro baten eremu bat beste erregistro bat izan daiteke. Esate baterako, ikusi jarraian nola deklaratzen den DM_rdLangile erregistroa bere barnean DM_rdData erregistroa daukana:





    ...
            type
               DM_rdData = record
                               iUrtea: integer ;
                              byHilea: byte ;
                              byEguna: byte ;
                           end ;   
               DM_rdLangile = record
                                 sIzena          : string[39] ;
                                 cKategoria      : char ;
                                 rdJaioteguna    : DM_rdData ;
                                 rdAintzinatasuna: DM_rdData ;
                              end ;
            var
               rdMekanikoa: DM_rdLangile ;
    ...




    Datu-motaren eskema bat eginez:






    rdMekanikoa aldagaian datuak sartzeko bi bide ditugu. Puntu konektorea birritan erabili edo bestela WITH klausula erabili. Ondoko esleipenak zuzenak dira eta edozein modutan irudian erakusten den emaitza lortuko dugu:





    Puntu lokailua birritan erabiliz: 





    ...
            rdMekanikoa.sIzena := 'Alain' ;
            rdMekanikoa.cKategoria := 'B' ;
            rdMekanikoa.rdJaioteguna.iUrtea := 1975 ;
            rdMekanikoa.rdJaioteguna.byHilea := 11 ;
            rdMekanikoa.rdJaioteguna.byEguna := 27 ;
            rdMekanikoa.rdAintzinatasuna.iUrtea := 1997 ;
            rdMekanikoa.rdAintzinatasuna.byHilea := 10 ;
            rdMekanikoa.rdAintzinatasuna.byEguna := 30 ;
    ...




    WITH klausularen bitartez aurreneko rdMekanikoa. zatia ken daiteke: 





    ...
            with rdMekanikoa do
            begin
               sIzena := 'Alain' ;
               cKategoria := 'B' ;
               rdJaioteguna.iUrtea := 1975 ;
               rdJaioteguna.byHilea := 11 ;
               rdJaioteguna.byEguna := 27 ;
               rdAintzinatasuna.iUrtea := 1997 ;
               rdAintzinatasuna.byHilea := 10 ;
               rdAintzinatasuna.byEguna := 30 ;
            end ;
    ...





    WITH klausulak onartzen du bigarren puntua kentzea. Datu-motaren definizioaren arabera WITH klausula erabiltzean kontuz ibili behar da; esate baterako, aurreko adibidean ezinezkoa zaigu puntu konektorea kentzea rdAintzinatasuna identifikadorearekin lan egitean: 





    ...
            with rdMekanikoa, rdJaioteguna do
            begin
               sIzena := 'Alain' ;
               cKategoria := 'B' ;
               iUrtea := 1975 ;
               byHilea := 11 ;
               byEguna := 27 ;
               rdAintzinatasuna.iUrtea := 1997 ;
               rdAintzinatasuna.byHilea := 10 ;
               rdAintzinatasuna.byEguna := 30 ;
            end ;
    ...





    WITH klausulak ebaluatu behar dituen erregistroak aldatuz (rdMekanikoa eta rdAintzinatasuna idazten badira) puntuak horrela jarri beharko lirateke: 





    ...
            with rdMekanikoa, rdAintzinatasuna do
            begin
               sIzena := 'Alain' ;
               cKategoria := 'B' ;
               rdJaioteguna.iUrtea := 1975 ;
               rdJaioteguna.byHilea := 11 ;
               rdJaioteguna.byEguna := 27 ;
               iUrtea := 1997 ;
               byHilea := 10 ;
               byEguna := 30 ;
            end ;
    ...



    Erregistro batek beste erregistro bat duenaren adibibide hau aztertu: ErregistroakErregistroetan_WITH.pas


    PARAMETRO IZATEAN JOKAMOLDEA



    Erregistro bat datu-mota egituratua delako, beti erreferentziaz pasatuko dugu azpiprogrametara. Horregatik, azpiprograma batean honela agertuko da jokamoldearen arabera:


    • Irteerakoa denean parametro formalak VAR marka izango du aurrean

    • Sarrerakoa denean parametro formalak CONST marka izango du aurrean


    Gogoratu arrayek modu beretsuan jokatzen zutela.
    ERREGISTRO BAT ITZULTZEN DUEN AZPIPROGRAMA: FUNTZIOA EDO PROZEDURA



    Demagun erregistro baten eremuak azpiprograma baten barruan datuz betetzen direla eta azpiprogramak erregistroa programa nagusira itzuli egiten duela. Zer azpiprograma mota erabiliko dugu, funtzioa ala prozedura? Deiak hauek lirateke:


    ErregistroaBete(rdIkaslea) ;          { prozedura BAI }
    rdIkaslea := fnrdErregistoaBete ;     {     funtzioa EZ }

    Prozesaketa batean erregistro bat aldatzeko, ez dugu funtziorik erabiliko. Erregistro bat azpiprograma baten bitartez prozesatzean aldatuko bada, beti prozedura erabiliko dugu. Gogoratu galdera bera arrayekin berdin erantzuten zela. Egoera biak hemen adierazten dira: Datu-mota eta azpiprogramak. 
    ADIBIDEAK



    Hona hemen erregistroen zenbait programa:

















    INTEGER REAL BOOLEAN CHAR STRING ARRAY RECORD FILE



     



    ordua: iruzkinik ez:
    Etiketak: , ,
    Harpidetu honetara: Mezuak (Atom)